3DS Max - Quad Bridge - Quick Question

Ace-Angel

Hey to all,

Could someone check and see if in their 3DS Max they have the Bridge function which could be used for a Quad menu, with settings enabled?

Here is what I mean:



I just took a gander, and in 3DS Max, I only have Bridge under Edit Poly Group, but it doesn't have a unified function (EI: I cannot select the click bridge OR the Settings bridge, like connect, extrude and bevel have) instead, I need to have 2 separate functions as you can see.

Apparently, a google search shows me that it doesn't exist. Anyone can shed some light on this issue?

Forgot to mention that Relax is also in the same Boat, I had to choose Relax Option because the standard Relax refused to work, anyone has this problem?

Ruramuq

Bridge was never included/finished, for quads/macros, since the day they introduced bridge if I remember well, ..for relax you might solve it by editing or creating a .mcr

$.PopupDialog #Bridge
-- Runtime error: Unrecognized code: #Bridge

$.PopupDialog #Relax

try to edit one that works, like extrude, max will open(read only) the .mcr file that contains all the macros, there you can copy one of those as a template to create your own .mcr

On AltExecute type do (...

Ace-Angel

Wow, that is really sad. Thanks for the help, I'll poke around Max and see what I can come up with.

Cheers.

Ruramuq

I found a way, when reading 'edit poly' mod docs
but it's not documented for editable_poly:

basically replaced #bridge for #bridgeBorder,
and for baseobjects, for numbers: 22 and 23 that I got using GetCommandMode() :

MacroScript EPoly_Bridge
enabledIn:#("max", "viz") --polycount
ButtonText:"Bridge"
Category:"Editable Polygon Object" 
internalCategory:"Editable Polygon Object" 
Tooltip:"Bridge (Poly) +" 
(
    -- Active in Edge, Border, Face, Element levels:
    On IsEnabled Return Filters.Is_EPolySpecifyLevel #{3..5}
    On IsVisible Return Filters.Is_EPolySpecifyLevel #{3..5}
    On IsChecked Do (
        try (
            local A = Filters.GetModOrObj()
            local mode = A.GetCommandMode()
            if (Filters.Is_This_EditPolyMod A) then
            (
                (mode == #BridgeBorder) or (mode == #BridgePolygon)
            )
            else (mode == 22 or mode == 23)
        )
        catch ( false )
    )

    On Execute Do (
        Try    (
            If SubObjectLevel == undefined then Max Modify Mode
            -- default to Edge:
            if subobjectLevel < 2 then subobjectLevel = 2
            local A = Filters.GetModOrObj()
            msl = A.GetMeshSelLevel ()
            if (Filters.Is_This_EditPolyMod A) then
            (
                if msl == #Edge then (A.toggleCommandMode #BridgeBorder)
                if msl == #Face then (A.toggleCommandMode #BridgePolygon)
            )
            else
            (
                if msl == #Edge then (A.toggleCommandMode 22)
                if msl == #Face then (A.toggleCommandMode 23)
            )
        )
        Catch(MessageBox "Operation Failed" Title:"Poly Editing")
    )
    On AltExecute type do (
        Try (
            If SubObjectLevel == undefined then Max Modify Mode
            -- default to Face level:
            if subobjectLevel == 0 then subobjectLevel = 4
            local A = Filters.GetModOrObj()
            local level = A.GetMeshSelLevel()
            if (level == #edge) then A.PopupDialog #BridgeBorder
            else if (level == #face) then A.PopupDialog #BridgePolygon
        )
        Catch(MessageBox "Operation Failed" Title:"Poly Editing")
    )
)

Ace-Angel

Wow, bloody nice one! It's works perfectly!

Amazing work my good Sir! Much appreciated!