Get vert index from TVert index, 3dsmax

asfalton · Mar 2015

Hi,

I'm trying to get vertex world position (A) from one specific texture vertex (B) from UV, is there an simple method to that in max script.

The thing is, that I have a model of a tree with thousands of leaves, I want to animate them, so and i need the position in space of every leave is attached to branches(that vert from UV).

Please help!
:poly121:

Eryk

RN · Mar 2015

Hello. The MaxScript documentation has a section precisely on this (in item "Finding the corresponding vertices"):

http://docs.autodesk.com/3DSMAX/14/ENU/MAXScript%20Help%202012/files/GUID-CBBA20AD-F7D5-46BC-9F5E-5EDA109F9CF-1078.htm#GUID-0D91093D-1C6E-450F-A694-D43942DE9549

Then using the following:

- http://docs.autodesk.com/3DSMAX/14/ENU/MAXScript%20Help%202012/files/GUID-496CE46A-EBD3-40C2-9637-3F21E0F0B0F-1235.htm#WS3ED54CBA79FF2E3D35B6E40512B7835CAF4-603C
- http://docs.autodesk.com/3DSMAX/14/ENU/MAXScript%20Help%202012/files/GUID-A97DF4E3-04A7-4A91-AE7C-3C75A8BAA39-1071.htm#TOC_ENTRY__d28e361013

-- With a mesh object with the Unwrap UVW modifier...

myObject = selection[1]

-- Not sure if the following is required, I imagine it is.

max modify mode
modPanel.setCurrentObject myObject.Unwrap_UVW

-- Take the index of the first selected map (UV) vertex.

selectedMapVertices = ( unwrap.getSelectedVertices myObject ) as array
mapVertexIndex = selectedMapVertices[1]

-- Identify the first of all the map faces using this map vertex.

mapFacesUsingVertex = ( meshop.getMapFacesUsingMapVert myObject 1 #( mapVertexIndex ) ) as array
mapFaceIndex = mapFacesUsingVertex[1] -- This map face index is the same as the corresponding mesh face index.

-- Get the corresponding mesh vertex from the face.

mapFaceMapVertices = meshop.getMapFace myObject 1 mapFaceIndex

local triangleVertexOrder = -1
if ( mapFaceMapVertices[1] == mapVertexIndex ) do triangleVertexOrder = 1
if ( mapFaceMapVertices[2] == mapVertexIndex ) do triangleVertexOrder = 2
if ( mapFaceMapVertices[3] == mapVertexIndex ) do triangleVertexOrder = 3

-- Finally, get the real mesh vertex that corresponds to the map vertex.

meshVertexIndex = ( getFace myObject mapFaceIndex )[triangleVertexOrder]

-- The world position of the vertex is the following.

in coordsys world
(
	position = getVert myObject meshVertexIndex
)

It's been a while since I last wrote in MaxScript, so you'll need to fix some syntax etc.

EDIT: Corrected some things.

monster · Mar 2015

Kryzon, answer is correct, but I believe that part of the help file was written before the getSelectedGeomVerts() function was added.

It's easier now that you don't have to compare UV and Geo Verts from faces.

(
	--GET SELECTED GEO VERTS FROM SELECTED UV VERTS
	uvMod = modPanel.getCurrentObject()
	selVerts = uvMod.getSelectedGeomVerts()

	--COPY TO A MESH SO WE DON'T HAVE TO DEAL WITH EDIT POLY/MESH/MODS
	objMesh = selection[1].mesh
	objOffset = selection[1].pos
	
	--PRINT THE WORLD POSITIONS OF THE SELECTED GEO VERTS
	for i = 1 to selVerts.count where selVerts[i] == true do
	(
			print ((meshOp.getVert objMesh i) + objOffset)
	)
)

RN · Mar 2015

That's interesting. The old method is from 3ds Max 9.

I see that that new function is only listed in the cloud help:

http://knowledge.autodesk.com/support/3ds-max/learn-explore/caas/CloudHelp/cloudhelp/2015/ENU/MAXScript-Help/files/GUID-830F23A3-E594-476D-B531-631BCD72EB42-htm.html

monster · Mar 2015

Honestly, I have lots of trouble looking though the MaxScript help ever since they got rid of CHM. When I look for info I typically do something like this:

uvMod = modPanel.getCurrentObject()
for i in getInterfaces uvMod do showInterface i

Get vert index from TVert index, 3dsmax

Replies