Remap Clean remove (CTRL+Backspace) in 3ds Max 2010

Sparx_25

Can someone please help me with remaping the clean remove function on another key (alt+y) in 3DS Max 2010? By clean remove I mean that, when i have selected one edge and i want to remove it with vertecies associated with that edge but only in that case when the vertecies connect only 2 edges.I am customizing keyboard shortcut layout only on the left side of my keyboard, and hitting CTRL+backspace is totally out of my left hand boundary . I have tried almost every remove function in cutomize keyboard menu, but it only removes the edge without the associated vertecies. It looks like clean remove is missing there. I have already used keyboard shortcut override toggle. I am affraid that i will have to use some macroscript for clean remove, but I am totally lost in this area....

Swordslayer

If you want to use a macroscript, something like this could get the job done:

macroscript cleanEdgeRemove
	category:"Advanced"
	tooltip:"Clean Edge Remove"
	buttonText:"Clean Remove"
(
	on isEnabled return
		selection.count == 1 AND getCommandPanelTaskMode() == #modify AND
		(isKindOf (modPanel.getCurrentObject()) Editable_Poly OR isKindOf (modPanel.getCurrentObject()) Edit_Poly) AND
		subObjectLevel == 2

	on execute do
	(
		local currObj = modPanel.getCurrentObject()
		local enumOpEdge = if isKindOf currObj Edit_Poly then #RemoveEdge else #Remove
		local enumOpVert = if isKindOf currObj Edit_Poly then #RemoveVertex else #Remove
		
		with redraw off
		(
			currObj.convertSelection #Edge #Vertex
			local selectedVerts = currObj.getSelection #Vertex
			currObj.buttonOp enumOpEdge
			currObj.setSelection #Vertex selectedVerts
			if isKindOf currObj Editable_Poly do subObjectLevel = 1
			currObj.buttonOp enumOpVert
			subObjectLevel = 2
		)
	)
)

(evaluate it and you will find the script in the Advanced category)

Noors

nervermind

Sparx_25

Thx swordslayer but that script delete not only the edge I want to remove but also edges, which are connected to that edge. The script I was looking for is in this thread: http://www.polycount.com/forum/showthread.php?p=1384800#post1384800