[3d max] UV Editor and unwrapping

Piotrherm

Hi there, 2 questions from UV Editor in 3d max.
1. Is there (in UV Editor) any tool like 'lattice tool' (as it is in Maya) or FFD modifier (similar when you modify geometry in 3d max)?
2.  When you Pack UVs, you can set padding manually, but is there a tool that allows you to set up space according to size of texture (like in Maya there is an option "Spacing presets: 64 Map, 256 Map etc")?
Thanks!

musashidan

1 you can use soft selection. In 2017 there is a dedicated brush for this.

2 from the editor options /prefs you can set map and grid size

Piotrherm

1. no, soft selection is just a different tool.

Revel

For question 1 you can use TexTools for that. Convert your mesh into UV shape > FFD > convert back to mesh with FFDed UV. If you're looking for build in feature I don't think there's any.

3ds Max UV viewport and modelling viewport is so 'detached', there's not even any lasso selection for UV viewport.

Piotrherm

Oh yeah, good suggestion about the Textools.

I can't believe that 3d max doesn't have such elementary tools from ages

Also for instance: combining and separating objects
You cannot just select couple of separated objects, click 1 button, and combine into one object (you have to choose options for Attach etc - it's so stupid and annnoying )

And opposite direction: One object consisted from couple of separated elements - if you want to separate such object into separated elements, you have to do it one by one 'detaching' them - its also very annying
It's time to move to Maya probably

Piotrherm

BTW, Textools has stopped on version 4.10 and no one develop it, right?

Revel

Yeah TexTools 4.10 works nice till now so we can still use it.

If you want to combine man object at once, you can select all of them and click the "Collapse" button on the Utilities tab, it'll combine all into one object.

For exploding elements or any other simple operations, you can maxscript it or just do a google search, most likely Scriptspot has it.

monster

Piotrherm said:

...I can't believe that 3d max doesn't have such elementary tools from ages
...
It's time to move to Maya probably

Because Maya never needs simple scripts for basic tasks.
Anyway, here's a couple of scripts for you:

Combining

--SCRIPT TO COMBINE ALL SELECTED MESH OBJECTS
(
	local proceed,Objs,firstObj

	--GET THE SELECTION AS ARRAY
	Objs = getcurrentSelection()

	--TEST ALL THE OBJS FOR VALIDITY
	proceed = true
	for obj in Objs do
	(
		if not (canConvertTo obj Editable_Poly) do
		(
			proceed = false
			exit
		)
	)
	
	undo "Combine Objects" on
	(
		if proceed do
		(
			--DELETE THE REFERENCE TO THE FIRST ITEM OF THE SELECTION ARRAY
			deleteItem Objs 1
			firstObj = convertToPoly(selection[1])

			--ATTACH ALL OTHER ITEMS TO THE FIRST NODE.
			for obj in objs do
			(
				firstObj.attach obj firstObj
			)
		)
	)
)

Seperating...

--SCRIPT THAT DETACHES ALL ELEMENTS OF A MODEL INTO SEPERATE OBJECTS
--OPPOSITE OF MODELING_COMBINEOBJECTS
undo "Detach All Elements" on
(
	pDetachFaces = polyop.detachFaces
	pGetElementsUsingFace = polyop.getElementsUsingFace
	pGetNumFaces = polyop.getNumFaces
	
	with redraw off
	(
		max create mode
		SelArray = getCurrentSelection()
		newSelection = #()

		for obj in SelArray do
		(
			baseName = obj.name
			baseParent = obj.parent
			obj.name = "Detaching..."
			ResetXForm obj
			
			newObjs = #()
			convertTo obj Editable_Poly
			
			while pGetNumFaces obj > 1 do
			(
				pDetachFaces obj (pGetElementsUsingFace obj #{1}) delete:true asNode:true name:(uniqueName baseName)
				append newObjs (objects[objects.count])
			)

			newObjs.parent = baseParent
			
			delete obj		
			join newSelection newObjs
		)
		
		CenterPivot newSelection
		select newSelection
	)
)