Home› Technical Talk
The BRAWL² Tournament Challenge has been announced!

It starts May 12, and ends Sept 12. Let's see what you got!

https://polycount.com/discussion/237047/the-brawl²-tournament

Maxscript making a self installing mzp

Kingblue
Kingblue
polycounter lvl 8
Offline / Send Message
Kingblue polycounter lvl 8
I've made my first script. I've searched the help but really couldn't find a method to
declare folders, how to make my ms script a mzp self installing file and so on. The sources I've read say different things (for example the path to place the ms file in).
Any suggestion would really help me shed some light on the problem.
· Share on FacebookShare on Twitter

Replies

  • monster
    Offline / Send Message
    monster polycounter
    If it's just a single file I would just make it available for download.

    An MZP file is a zip file with the extension renamed. The easiest method I've found to use MZP files is to have it launch another maxscript and then let that finish the work. Inside the MZP file you should have a file named mzp.run with contents similar to this:
    1. name "My Tool"
    2. version 1.0
    3.  
    4. extract to $temp\mytool
    5.  
    6. run installer_mytool.ms
    7. drop installer_mytool.ms
    8.  
    9. clear temp on MAX exit

    The mzp.run file is capable of doing more operations, but I haven't had much success with that. That's why I just have it run another MaxScript. You can have installer_mytool.ms delete any previous verion, copy the script to the proper location, evaluate the file, and finally prompt that installation failed or was successful.
    · Share on FacebookShare on Twitter
  • miauu
    Offline / Send Message
    miauu polycounter lvl 15
    Go here and dlownload RTTAssist_1.6.mzp
    Unzip the mzp in separate folder. You will find all files that monster mentoined. The install.ms uses some DOS commands and creates new folders, move the ms, mcr. and icon files etc.
    Also, you can download ToTex and take a look into his install.ms file - HiddenDOSCommand is used.
    Oitliner ver 2 have installe.ms that is use dotNet for createing folders.
    Get what is best for you and use it.
    :)

    P.S. you can use the mzp.run to create folders and move the files, but in Win Vista, Win7, you have to ruun the max and the MZP as adnimistrator.
    · Share on FacebookShare on Twitter
  • Kingblue
    Offline / Send Message
    Kingblue polycounter lvl 8
    Ok, I'm starting to make some order in my mind. Here are the steps that I've traced so far.

    1. Put your script and icon files in a zip file and rename it to mzp.
    2. Write a text file with instructions to copy the folder contained in the mzp file to windows temp directory. You can't
    do it directly,you must delegate another ms.file (already stored in the mzp file). Save this as mzp.run
    Example

    name "John Doe"

    Version Beta

    extract to $temp/johndoe
    run "johndoeinstaller.ms"
    drop "johndoeinstaller.ms"

    clear temp


    3.Compile the delegate johndoeinstaller.ms file that shall do the installation operations like copying files and so on. Here I'm lost again.
    Can you suggest some info on this?
    · Share on FacebookShare on Twitter
  • miauu
    Offline / Send Message
    miauu polycounter lvl 15
    Did you examine the code of the installers, that I mentioned above?
    For exampel RTTAssist installer:
    the mzp.run code
    1. name "RTTAssist"
    2. version 1.6
    3.  
    4. treeMove "tempRTTAssistFolder" to "$temp"
    5.  
    6. run "RTTAssistInstall.ms"
    7. drop "RTTAssistInstall.ms"
    8.  
    9. clear temp
    The RTTAssistInstall file that do the installation - copy files, create directories.
    1. --******************************************************************************************************
    2. -- Created:         12-06-2011
    3. -- Last Updated:    25-07-2011
    4. --
    5. -- Author :  Kostadin Kotev / miau_u@yahoo.com /
    6. -- Version:  3ds max 2009 and up
    7. --
    8. -- Discription: 
    9. --    RTTAssist Install file
    10. --******************************************************************************************************
    11. -- MODIFY THIS AT YOUR OWN RISK
    12.  
    13. (
    14.     global RTTAssist_Instalation
    15.     try ( destroyDialog RTTAssist_Instalation ) catch ()
    16.     try ( destroyDialog miauuRTTassist ) catch ()
    17.     rollout RTTAssist_Instalation "RTTAssist 1.6 Setup"
    18.     (
    19.         local tempRTTAssistFolder = pathConfig.GetDir #temp+"\\tempRTTAssistFolder"
    20.         local usRTTAui = pathConfig.GetDir #userscripts+"\\RTTAssistUI"
    21.         local usRTTAuiIco = pathConfig.GetDir #userscripts+"\\RTTAssistUI\\RTTAssistIcons"
    22.         local usRTTAuiPrst01 = pathConfig.GetDir #userscripts + "\\RTTAssist"
    23.         local usRTTAuiPrst02 = pathConfig.GetDir #userscripts + "\\RTTAssist\\Presets"
    24.         
    25.         ImgTag ImgTag_BG bitmap:(bitmap 2 2 color:gray) pos:[0,0]  \
    26.             width:309 height:194 opacity:1 transparent:(color 0 255 255) enabled:off
    27.  
    28.         hyperLink httpOficialSite "Oficial Site" pos:[213,138] color:(color 176 208 231) hoverColor:(color 82 129 181) visitedColor:(color 65 81 100) address:"http://vertexbee.com/rttassist.htm"
    29.         hyperLink httpVideos "Videos" pos:[213,152] color:(color 176 208 231) hoverColor:(color 82 129 181) visitedColor:(color 65 81 100) address:"http://www.youtube.com/user/RTTassist?feature=mexp"
    30.         ImgTag it_License bitmap:(bitmap 2 2 color:white) pos:[213,166]  \
    31.             width:36 height:9 opacity:1 transparent:(color 0 255 255)
    32.         
    33.         button btn_Install "Install" width:138 height:30 pos:[30,103]
    34.         button btn_Uninstall "Uninstall" width:138 height:30 pos:[30,145]
    35.  
    36.         
    37.         function DeleteDirAndSubDir rootDir =
    38.         (
    39.             try ( DOSCommand ("rmDir \"" + rootDir + "\" /s /q") ) catch (messagebox "Can't delete RTTAssist folders!" title:"RTTAssist Install Error!!!")
    40.         )
    41.         function DeleteFiles curDir file =
    42.         (
    43.             filesToDelete = getFiles (curDir + file)
    44.             for f in filesToDelete do    deleteFile f
    45.         )
    46.         
    47.         function ValidateDirectory _dirNameIn  =
    48.         (
    49.             local _dirName = copy _dirNameIn
    50.             local c
    51.             for i = _dirName.count to 1 by -1 while (c=_dirName[i]; c=="\\" or c== "/") do
    52.                 _dirName = subString _dirName 1 (i-1)
    53.             
    54.             if doesFileExist _dirName then
    55.                 dirExists = true
    56.             else
    57.                 dirExists = false
    58.             
    59.             return dirExists
    60.         )
    61.         function InstalRTTAssist =
    62.         (
    63.             if tempRTTAssistFolder != "" then
    64.             (
    65.                 --    create main, icons and preset folders
    66.                 local rttAssistMainFolder = (makeDir usRTTAui)
    67.                 local iconFolder = (makeDir usRTTAuiIco)
    68.                 local presetFolder01 = (makeDir usRTTAuiPrst01)
    69.                 local presetFolder02 = (makeDir usRTTAuiPrst02)
    70.                 
    71.                 if presetFolder02 != true then
    72.                 (
    73.                     messagebox "Unable to create \"Preset\" folder" title:"RTTAssist Installation Error!!!"
    74.                 )
    75.                 else
    76.                 (
    77.                     --    copy icons and UI files
    78.                     if iconFolder == true then
    79.                     (
    80.                         allPreinstPNGfiles = (getFiles (tempRTTAssistFolder+"\\RTTAssistUI\\RTTAssistIcons\\*.png"))
    81.                         for pngFile in allPreinstPNGfiles do
    82.                         (        
    83.                             copyFile pngFile (usRTTAui+"\\RTTAssistIcons\\"+filenameFromPath pngFile)
    84.                         )
    85.                         allInstalledPNGfiles = (getFiles (usRTTAui+"\\RTTAssistIcons\\*.png"))                        
    86.                         if allInstalledPNGfiles.count != allPreinstPNGfiles.count do messagebox "Installation Error!!!" title:"RTTAsssist"
    87.                     )
    88.                     else
    89.                         messagebox "Unable to create \"RTTAssist Icons\" folder" title:"RTTAssist Installation Error!!!"
    90.                     --    copy htm, ini, license and ms files
    91.                     if rttAssistMainFolder == true then
    92.                     (        
    93.                         allPreinstMCIfiles = (getFiles (tempRTTAssistFolder+"\\RTTAssistUI\\*.*"))
    94.                         for mciFile in allPreinstMCIfiles do
    95.                         (    
    96.                             copyFile mciFile (usRTTAui+"\\"+filenameFromPath mciFile)                        
    97.                         )
    98.                         allInstalledMCIfiles = (getFiles (usRTTAui+"\\*.*"))                        
    99.                         if allInstalledMCIfiles.count != allPreinstMCIfiles.count do messagebox "Installation Error!!!" title:"RTTAsssist"
    100.                     )
    101.                     else
    102.                         messagebox "Unable to create main \"RTTAssist\" folder" title:"RTTAssist Installation Error!!!"
    103.                     --    copy toolbar Icons
    104.                     for tBarIcoFiles in (getFiles (tempRTTAssistFolder+"\\icons\\*.*")) do
    105.                     (    
    106.                         copyFile tBarIcoFiles (pathConfig.GetDir #userIcons+"\\"+filenameFromPath tBarIcoFiles)
    107.                     )
    108.                     --    copy RTTAssist macro
    109.                     if (copyFile (tempRTTAssistFolder+"\\Macro_RTTAssist.mcr") (usRTTAui+"\\Macro_RTTAssist.mcr")) then
    110.                     (    --    load macro
    111.                         fileIn (usRTTAui+"\\Macro_RTTAssist.mcr")
    112.                          --    start RTTAssist
    113.                         try(fileIn (usRTTAui+"\\RTTAssist.ms"))
    114.                         catch(messagebox "Please, start RTTAssist manualy!" title:"RTTAssist")
    115.                     )
    116.                     else
    117.                         messagebox "Can't copy the macro file of RTTAssist!" title:"RTTAssist Installation Error!!!"
    118.                 )
    119.             )
    120.             else
    121.                 messagebox "Insallation Error!!!" title:"RTTAsssist"
    122.         )
    123.         
    124.         on RTTAssist_Instalation open do
    125.         (
    126.             if tempRTTAssistFolder != "" then 
    127.             (
    128.                 ImgTag_BG.bitmap = (openBitmap (tempRTTAssistFolder+"\\RTTAssistInstallBG.png"))
    129.                 it_License.bitmap = (openBitmap (tempRTTAssistFolder+"\\miauuITlicense.png"))
    130.             )
    131.             
    132.             if onlineUpdate == true do
    133.             (
    134.                 if (doesFileExist ((getDir #userscripts) + "\RTTAssistUI\RTTAssist.ms")) do
    135.                 (                    
    136.                     DeleteFiles ((getDir #userscripts) + "\RTTAssistUI") "*.*"    --    delete the ms, ini and help file
    137.                     DeleteFiles ((getDir #userscripts) + "RTTAssistIcons") "*.*"    --    delete the icons
    138.                     DeleteDirAndSubDir ((getDir #userscripts) + "\RTTAssistUI")    --    delete folders                    
    139.                     DeleteFiles (getDir #userMacros) "*RTTAssist*.*"    --    delete macro
    140.                     DeleteFiles ("$max\\ui\\macroscripts\\") "Macro_RTTAssist.mcr"
    141.                 )
    142.                 InstalRTTAssist()
    143.                 destroydialog RTTAssist_Instalation
    144.             )
    145.         )
    146.         on it_License lbuttondown do
    147.         (
    148.             licFile = tempRTTAssistFolder+"\license.html"
    149.             shelllaunch licFile ""
    150.         )
    151.         on it_License mouseover do
    152.         (
    153.             it_License.bitmap = (openBitmap (tempRTTAssistFolder+"\\miauuITlicenseHover.png"))
    154.         )
    155.         on it_License mouseout do
    156.         (
    157.             it_License.bitmap = (openBitmap (tempRTTAssistFolder+"\\miauuITlicense.png"))
    158.         )        
    159.         on RTTAssist_Instalation close do
    160.         (
    161.             if tempRTTAssistFolder != "" then
    162.                 DeleteDirAndSubDir tempRTTAssistFolder
    163.         )
    164.         
    165.         on btn_Install pressed do
    166.         (
    167.             if tempRTTAssistFolder != "" then
    168.             (
    169.                 --    create RTTAssistUI directory
    170.                 if (ValidateDirectory usRTTAui) == false then
    171.                 (--    if RTTAssistUI folder does not exist start new installation
    172.                     InstalRTTAssist()
    173.                     destroydialog RTTAssist_Instalation
    174.                 )
    175.                 else
    176.                 (--    if RTTAssistUI folder exist show upgrade dialog
    177.                     try(destroyDialog ReinstallUpgrade)catch()
    178.                     rollout ReinstallUpgrade "RTTAssist 1.6"
    179.                     (
    180.                         label lb1 "RTTassist has already been installed!" pos:[20,20]
    181.                         label lb2 "To reinstall or update RTTAssist press \"Continue\"." pos:[20,40]
    182.                         label lb "To cancel the operation press \"Cancel\"."    pos:[20,60]
    183.                         
    184.                         button btn_Continue "Continue" pos:[150,90] width:50
    185.                         button btn_Cancel "Cancel" pos:[210,90] width:50
    186.                         
    187.                         on btn_Continue pressed do
    188.                         (
    189.                             if (doesFileExist ((getDir #userscripts) + "\RTTAssistUI\RTTAssist.ms")) or \
    190.                                 (doesFileExist ((getDir #userscripts) + "\RTTAssistUI\RTTAssist.mse")) do
    191.                             (                                
    192.                                 DeleteFiles ((getDir #userscripts) + "\RTTAssistUI") "*.*"    --    delete the ms, ini and help file
    193.                                 DeleteFiles ((getDir #userscripts) + "\RTTAssistIcons") "*.*"    --    delete the icons
    194.                                 DeleteDirAndSubDir ((getDir #userscripts) + "\RTTAssistUI")    --    delete folders                                
    195.                                 DeleteFiles ((getDir #userMacros) + "\\") "*RTTAssist*.*"    --    delete macro                                 
    196.                                 DeleteFiles ("$max\\ui\\macroscripts\\") "Macro_RTTAssist.mcr"
    197.                             )
    198.                             InstalRTTAssist()
    199.                             destroydialog ReinstallUpgrade
    200.                             destroydialog RTTAssist_Instalation    
    201.                         )
    202.                         
    203.                         on btn_Cancel pressed do
    204.                         (
    205.                             destroydialog ReinstallUpgrade
    206.                         )
    207.                     )
    208.                     createdialog ReinstallUpgrade height:120 width:275 bgcolor:white fgcolor:red modal:true                        
    209.                 )
    210.             )
    211.             else
    212.                 messagebox "Insallation Error!!!" title:"RTTAsssist"
    213.         )
    214.         
    215.         on btn_Uninstall pressed do
    216.         (
    217.             if (doesFileExist ((getDir #userscripts) + "\RTTAssistUI\RTTAssist.ms")) or \
    218.                 (doesFileExist ((getDir #userscripts) + "\RTTAssistUI\RTTAssist.mse")) do
    219.             (                
    220.                 DeleteFiles ((getDir #userscripts) + "\RTTAssistUI") "*.*"    --    delete the ms, ini and help file
    221.                 DeleteFiles ((getDir #userscripts) + "\RTTAssistIcons") "*.*"    --    delete the icons
    222.                 DeleteDirAndSubDir ((getDir #userscripts) + "\RTTAssistUI")    --    delete folders                
    223.                 DeleteFiles ((getDir #userscripts) + "\RTTAssist\Presets") "*.*"    --    delete the rpf and rps file
    224.                 DeleteDirAndSubDir ((getDir #userscripts) + "\RTTAssist")    --    delete folders
    225.                 DeleteFiles ((getDir #userMacros) + "\\") "*RTTAssist*.*"    --    delete macro                 
    226.                 DeleteFiles ("$max\\ui\\macroscripts\\") "Macro_RTTAssist.mcr"
    227.                 --    delete tempRTTAssistfolder
    228.                 if (tempRTTAssistFolder != "") then
    229.                     DeleteDirAndSubDir tempRTTAssistFolder
    230.                 
    231.                 destroydialog RTTAssist_Instalation
    232.                 
    233.                 rollout UninstallComplete "RTTAssist 1.6 Setup"
    234.                 (
    235.                     label lb1 "     Uninstallation complete." pos:[20,20]
    236.                     label lb2 "Thank you for using RTTAssist." pos:[20,40]
    237.                 )
    238.                 createdialog UninstallComplete height:70 width:185 bgcolor:white fgcolor:black
    239.             )
    240.         )
    241.     )
    242.     createDialog RTTAssist_Instalation height:194 width:309 bgcolor:gray
    243. )
    This installer uses some DOS commands
    The Totex installer uses HiddenDosCommand
    The Outliner installer uses dotnet
    Just check the codes and use what is best for you
    :)
    · Share on FacebookShare on Twitter
  • Kingblue
    Offline / Send Message
    Kingblue polycounter lvl 8
    I didn't think that copy and pasting files in Mxs was harder than making the script itself (being said that's my first script). Whew, I'll start deciphering it. Thanks
    · Share on FacebookShare on Twitter
  • monster
    Offline / Send Message
    monster polycounter
    Once you're an old pro like us, you'll have a build.ms that creates the mzp for you. :)
    · Share on FacebookShare on Twitter
  • miauu
    Offline / Send Message
    miauu polycounter lvl 15
    Go here and check of this tool will help you to create the mzp with less efforts
    · Share on FacebookShare on Twitter
  • Kingblue
    Offline / Send Message
    Kingblue polycounter lvl 8
    Thanks again, guys.
    · Share on FacebookShare on Twitter
Sign In or Register to comment.