Soft selection falloff hotkey for 3ds Max

Replies

• 
  Options

  Offline / Send Message

  Mark Dygert mod

  Aug 2014

  I don't think you can out of the box but with a little scripting you can create two macro's that can be hotkey'ed.
  
  I'm not sure how comfortable you are with maxscript so let me know if this seems like a bunch of gobbledygook.

  macroScript SoftSelFalloffPlus
  Category:"MyTools"
  toolTip:"Soft Sel Falloff Plus"
  buttontext:"SoftSel+"
  (
  	max modify mode
  	if classof (modPanel.getCurrentObject()) == Editable_Poly then (
  		$.useSoftSel = on
  		CurFall = $.falloff 
  		$.falloff = (CurFall + 10)
  	)
  	else (
  		if classof (modPanel.getCurrentObject()) == Edit_Poly then (
  			$.modifiers[#Edit_Poly].useSoftSel = on
  			CurFall = $.modifiers[#Edit_Poly].falloff 
  			$.modifiers[#Edit_Poly].falloff = (CurFall + 10)
  		)
  		else (messagebox "The currently selected modifier is not one of the following: \nEdit_Poly (modifier)\nEditable_Poly (object)\n\nPlease select the apporate modifier/object and try again." Title:"Modifier Stack Error")
  	)
  )
  
  macroScript SoftSelFalloffMinus
  Category:"MyTools"
  toolTip:"Soft Sel Falloff Minus"
  buttontext:"SoftSel-"
  (
  	max modify mode
  	if classof (modPanel.getCurrentObject()) == Editable_Poly then (
  		$.useSoftSel = on
  		CurFall = $.falloff 
  		$.falloff = (CurFall - 10)
  	)
  	else (
  		if classof (modPanel.getCurrentObject()) == Edit_Poly then (
  			$.modifiers[#Edit_Poly].useSoftSel = on
  			CurFall = $.modifiers[#Edit_Poly].falloff 
  			$.modifiers[#Edit_Poly].falloff = (CurFall - 10)
  		)
  		else (messagebox "The currently selected modifier is not one of the following: \nEdit_Poly (modifier)\nEditable_Poly (object)\n\nPlease select the apporate modifier/object and try again." Title:"Modifier Stack Error")
  	)
  )
  

  Install instructions:

  • Main Menu > MAXScript > New Script
  • Copy/Paste the text above and hit ctrl-E to run the code once, save it somewhere if you want to hang onto it, technically you don't have to, it just installed, but you might want to hang onto it if you re-install max or upgrade to a newer version.
  • Main Menu > Customize > Customize UI
  • Change the Category to My_Tools and set hotkeys for the two scripts

  Notes:

  • If you hold the key down it will keep going.
  • This only works on the currently selected modifier, if it is "Edit Poly" or "Editable Poly".
  • If you want it to cover more soft selects in more modifiers then you'll need a few more if-then-else statements.
  • Currently it will go up/down by "10". You can change that value in the script if you need it more/less precise.

  
  I hope that helps!

  0 · Share on FacebookShare on Twitter