Use Pivot Point Center

CompanionCube

Something is driving me crazy, and i feel kinda stupid asking, but i’ve looked the customize UI so many times for this top try and find an answer but i can’t.
it would really speed up my work if i could map the different options in ‘Use Pivot Point Center’ to a hotkey or add it into my quad menu.
please help?
thanks

Mark Dygert

Nope I don't think you can set shortcuts for it by default. But you can do it through maxscript.

macroScript PPCent
Category:"VigTools"
toolTip:"Pivot Point Center"
buttontext:"PPCent"
(
    toolMode.pivotCenter()
)

Copy and paste this script into a new maxscript, run it once Ctrl-E and then under Customize > Customize UI > Catagory VigTools you'll have PPCent you can bind this to a key or quadmenu.

If you want the other options just replace "toolMode.pivotCenter()" with one of the following and change the header info and run the script. Feel free to change the header to whatever you want, I use vigtools because well its easy for me to find.

toolMode.transformCenter()

Sets Coordinate System Center to Transform Coordinate System.

toolMode.selectionCenter()

Sets Coordinate System Center to Selection Center.

toolMode.pivotCenter()

Sets Coordinate System Center to Pivot Point Center.

If you want a single key to toggle through each of them that will take a tiny bit more work... but is easy enough to do.

CompanionCube

thanks dude, i think it would be useful to alot of people, so annoying to have to go to the top of the screen to access the "Use Pivot Point Center" when i can access the "Reference Coordinate system" through the quad menu.

SyncViewS

Here they are. Evaluate once and find them under category "Pivot Tools".

macroScript UsePivotPointCenter
category:"Pivot Tools"
buttonText:"Use Pivot Point Center"
toolTip:"Use Pivot Point Center"
(
    on execute do
        setCoordCenter #Local
)

macroScript UseSelectionCenter
category:"Pivot Tools"
buttonText:"Use Selection Center"
toolTip:"Use Selection Center"
(
    on execute do
        setCoordCenter #Selection
)

macroScript UseTransformCoordinateCenter
category:"Pivot Tools"
buttonText:"Use Transform Coordinate Center"
toolTip:"Use Transform Coordinate Center"
(
    on execute do
        setCoordCenter #System
)

EDIT: oops! Didn't see your edit, Vig

Mark Dygert

No prob, I beat you to the punch because I was lazy, heh. I was just about to edit the post and not be lazy when I saw yours.

Besides I like you're titles better, you can't make me give it back!

If you haven't given SyncViewS the right to raise your first born son as his own, you should do it now. Dude's a genius when it comes to maxscript. It must carry on!

CompanionCube

omg you guys are amazing! thanks so much, you just saved me so much time, trying out now.

CompanionCube

works perfect, thanks again so much, it should be standard to map these as hotkeys or in the quadmenu.

Mark Dygert

macroScript UsePivotPointCenter
category:"Pivot Tools"
buttonText:"Use Pivot Point Center"
toolTip:"Use Pivot Point Center"
(
    on execute do
        setCoordCenter #Local
)

macroScript UseSelectionCenter
category:"Pivot Tools"
buttonText:"Use Selection Center"
toolTip:"Use Selection Center"
(
    on execute do
        setCoordCenter #Selection
)

macroScript UseTransformCoordinateCenter
category:"Pivot Tools"
buttonText:"Use Transform Coordinate Center"
toolTip:"Use Transform Coordinate Center"
(
    on execute do
        setCoordCenter #System
)

macroScript UseToggle
category:"Pivot Tools"
buttonText:"Use Toggle Pivot"
toolTip:"Use Toggle Pivot"
(
fn centloc = (toolMode.transformCenter())
fn centsel = (toolMode.selectionCenter())
fn centpiv = (toolMode.pivotCenter())

if (getcoordcenter()) == #Local then 
    ( 
        centloc()
    )
else 
    (
        if (getcoordcenter()) == #selection then
            ( 
                centpiv()
            )
        else
        (
            if (getcoordcenter()) == #system then
                ( 
                    centsel()
                )
        )
    )
)

Here are the scripts SyncViewS wrote combined with a toggle I just wrote, so say you want J to cycle through the modes just bind "Toggle Pivot" to J.

SyncViewS

Hey Vig, smart idea the cycle!

CompanionCube

thats even better, thanks!

swytch

Is there a way to do something similar to Selection Sets? In other words, access any stored Selection Sets via the Quad Menu?